shithub: libtags

ref: 7e151f2b35585bd69900da623a12c80f3e20a6cf
dir: /meson.build/

View raw version 
project(
	'libtags',
	'c',
	version: '1.0',
	default_options: [
		'c_std=c99',
		'warning_level=3',
		'buildtype=debug',
	],
)

add_project_arguments(
	'-Wmissing-prototypes',
	'-Wformat=2',
	'-D_DEFAULT_SOURCE',
	language: 'c',
)

cc = meson.get_compiler('c')

if(cc.has_argument('-W#warnings'))
	add_project_arguments('-Wno-#warnings', language: 'c')
elif(cc.has_argument('-Wcpp'))
	add_project_arguments('-Wno-cpp', language: 'c')
endif

src_lib = [
	'437.c',
	'8859.c',
	'flac.c',
	'id3genres.c',
	'id3v1.c',
	'id3v2.c',
	'it.c',
	'm4a.c',
	'mod.c',
	'opus.c',
	's3m.c',
	'tags.c',
	'utf16.c',
	'vorbis.c',
	'wav.c',
	'xm.c',
]

src_readtags = [
	'examples/readtags.c',
]

lib = static_library(
	'tags',
	sources: src_lib,
	install: true,
)

install_headers(
	'tags.h',
)

libtags = declare_dependency(
	link_with: lib,
)

executable(
	'readtags',
	sources: src_readtags,
	dependencies: [ libtags ],
	install: false,
)