shithub: mc

ref: 09a34baac6757c7a4c33e3e3c50054acbb1b70bb
dir: /lib/std/fndup.myr/

use "alloc"
use "die"
use "sldup"
use "slcp"
use "types"

pkg std =
	generic fnenvsz	: (fn : @fn::function -> size)
	generic fndup	: (fn : @fn::function -> @fn::function)
	generic fnbdup	: (fn : @fn::function, buf : byte[:] -> @fn::function)
	generic fnfree	: (fn : @fn::function -> void)
;;

generic fndup = {fn
	var sl

	sl = std.slalloc(fnenvsz(fn))
	-> fnbdup(fn, sl)
}

generic fnenvsz = {fn
	var repr : intptr[2]

	repr = (&fn : intptr[2]#)#
	-> envslice(repr[0]).len
}

extern const put : (fmt : byte[:], args : ... -> int64)

generic fnbdup = {fn, buf
	var repr : intptr[2]
	var env

	repr = (&fn : intptr[2]#)#
	env = envslice(repr[0])
	slcp(buf[:env.len], env)
	repr[0] = (buf : intptr)
	-> (&repr : @fn::function#)#
}

generic fnfree = {fn
	var repr : intptr[2]

	repr = (&fn : intptr[2]#)#
	std.slfree(envslice(repr[0]))
}

const envslice = {ep : intptr
	var env : byte#
	var szp : intptr#

	if ep == 0
		-> [][:]
	;;
	env = (ep : byte#)
	szp = (env : intptr#)
	-> env[:szp#]
}